initial commit

.config/zsh/alias/diff.zsh

@@ -0,0 +1,3 @@
+#!/bin/zsh
+
+z-alt-set-static 'diff|. .' 'diff --color=auto|diff'

.config/zsh/alias/directories.zsh

@@ -0,0 +1,16 @@
+#!/bin/zsh
+
+## alias -g ...='../..'
+## alias -g ....='../../..'
+## ...
+for (( i=3 ; i < 10 ; i++ )) ; do
+    alias -g ${(l:i::.:)}='..'${(l:3*(i-2)::/..:)}
+done ; unset i
+
+alias -- -='cd -'
+alias 1='cd -'
+## alias 2='cd -2'
+## ...
+for (( i=2 ; i < 10 ; i++ )) ; do
+    alias $i="cd -$i"
+done ; unset i

.config/zsh/alias/grep.zsh

@@ -0,0 +1,24 @@
+#!/bin/zsh
+
+z-alt-grep() {
+    local -a a
+    a=( ${(@s:|:)1} )
+    [ ${#a} = 0 ] && a=( "$1" )
+    local n=${#a}
+    [ -z "$1" ] && n=0
+    case "$n" in
+    0) : do nothing ;;
+    *) z-alt-set-static "grep|-q -e ' ' ${ZSHU[d_zdot]}/.zshenv" "$1" "GREP_OPTIONS='' " ;;
+    esac
+}
+
+## TODO: add --exclude-dir={.bzr,CVS,.git,.hg,.svn,.idea,.tox}
+GREP_GNU='--color=auto'
+
+z-alt-grep "grep ${GREP_GNU}|grep"
+
+unfunction z-alt-grep
+unset GREP_GNU
+
+egrep() { grep -E "$@" ; }
+fgrep() { grep -F "$@" ; }

.config/zsh/alias/history.zsh

@@ -0,0 +1,6 @@
+#!/bin/zsh
+
+fc() { builtin fc -i "$@" ; }
+
+# alias history='z-history '
+history() { builtin fc -il "$@" ; }

.config/zsh/alias/idle.zsh

@@ -0,0 +1,9 @@
+#!/bin/zsh
+
+function {
+    local -a s
+    s+=( $(z-alt-find 'nice -n +40') )
+    s+=( $(z-alt-find 'chrt -i 0'  ) )
+    s+=( $(z-alt-find 'ionice -c 3') )
+    z-alt-set-static idle "$s|env"
+}

.config/zsh/alias/ls.zsh

@@ -0,0 +1,53 @@
+#!/bin/zsh
+
+if [ -z "${LS_COLORS}" ] ; then
+    (( $+commands[dircolors] )) && eval "$(dircolors -b)"
+fi
+
+case "${ZSHU[os_family]}" in
+bsd|darwin) export LSCOLORS="Gxfxcxdxbxegedabagacad" ;;
+esac
+
+__z_alt_ls() {
+    local -a a
+    a=( ${(@s:|:)1} )
+    [ ${#a} = 0 ] && a=( "$1" )
+    local n=${#a}
+    [ -z "$1" ] && n=0
+    case "$n" in
+    0) : do nothing ;;
+    *) z-alt-set-static 'ls|-d .' "$1" "LS_OPTIONS='' " ;;
+    # 1) z-alt-set-static  'ls|-d .' "$1" "LS_OPTIONS='' " ;;
+    # *) z-alt-set-dynamic 'ls|-d .' "$1" "LS_OPTIONS='' " ;;
+    esac
+}
+
+LS_GNU='--color=tty --group-directories-first'
+
+case "${ZSHU[os_type]}" in
+linux*)    alt="ls ${LS_GNU}|ls" ;;
+netbsd*)   alt="gls ${LS_GNU}|ls" ;;
+openbsd*)  alt="gls ${LS_GNU}|colorls -G|ls" ;;
+freebsd*)  alt="gls ${LS_GNU}|ls -G|ls" ;;
+darwin*)   alt="gls ${LS_GNU}|ls -G|ls" ;;
+*)         alt="ls ${LS_GNU}|ls" ;;
+esac
+
+__z_alt_ls "${alt}"
+
+unfunction __z_alt_ls
+unset alt LS_GNU
+
+[ -n "${LS_COLORS}" ] && zstyle ':completion:*' list-colors "${(s.:.)LS_COLORS}"
+
+case "${ZSHU[os_family]}" in
+linux) alias l='ls -lhF ' ;;
+bsd)   alias l='ls -lhIF ' ;;
+esac
+
+alias ll='ls -lAF '
+
+case "${ZSHU[os_family]}" in
+linux) alias lll='ls -lAn --full-time ' ;;
+bsd)   alias lll='ls -lAnT ' ;;
+esac

.config/zsh/alias/sudo.zsh

@@ -0,0 +1,4 @@
+#!/bin/zsh
+
+alias sudo-i='sudo -i'
+alias sudoi='sudo -i'

.config/zsh/alias/telnet.zsh

@@ -0,0 +1,6 @@
+#!/bin/zsh
+
+case "${ZSHU[os_type]}" in
+linux-gnu) alias tl='telnet -K ' ;;
+*bsd*)     alias tl='telnet -K -N -y ' ;;
+esac